Kā izmantot Excel LAMBDA funkciju -

Satura rādītājs

Kopsavilkums

Excel LAMBDA funkcija nodrošina iespēju izveidot pielāgotas funkcijas, kuras var atkārtoti izmantot visā darbgrāmatā bez VBA vai makro.

Mērķis

Izveidot pielāgotu funkciju

Atgriešanās vērtība

Kā definēts pēc formulas

Sintakse

= LAMBDA (parametrs,…, aprēķins)

Argumenti

  • parametrs - funkcijas ievades vērtība.
  • aprēķins - aprēķins, kas jāveic kā funkcijas rezultāts. Jābūt pēdējam argumentam.

Versija

Excel 365

Lietošanas piezīmes

Datorprogrammēšanā LAMBDA attiecas uz anonīmu funkciju vai izteicienu. Anonīma funkcija ir funkcija, kas definēta bez nosaukuma. Programmā Excel LAMBDA funkcija nodrošina veidu, kā definēt un iekapsulēt noteiktu formulu funkcionalitāti, līdzīgi kā Excel funkcija. Kad LAMBDA funkcija ir definēta, to var nosaukt un atkārtoti izmantot citur darbgrāmatā. Citiem vārdiem sakot, funkcija LAMBDA ir veids, kā izveidot pielāgotas funkcijas.

Viena no pielāgotās LAMBDA funkcijas galvenajām priekšrocībām ir tā, ka formulā ietvertā loģika pastāv tikai vienā vietā. Tas nozīmē, ka ir tikai viena koda kopija, kas jāatjaunina, novēršot problēmas vai atjauninot funkcionalitāti, un izmaiņas automātiski tiks izplatītas visos darbgrāmatas LAMBDA funkcijas gadījumos. LAMBDA funkcijai nav nepieciešama VBA vai makro.

1. piemērs | 2. piemērs | 3. piemērs

LAMBDA funkcijas izveide

LAMBDA funkcijas parasti tiek izveidotas un atkļūdotas darblapas formulu joslā, pēc tam tiek pārvietotas uz vārdu pārvaldnieku, lai piešķirtu nosaukumu, kuru var izmantot jebkur darbgrāmatā.

Pielāgotas formulas izveidošanai un izmantošanai, pamatojoties uz funkciju LAMBDA, ir četras pamata darbības:

  1. Pārbaudiet izmantoto loģiku ar standarta formulu
  2. Izveidojiet un pārbaudiet formulas vispārēju (nenosauktu) LAMBDA versiju
  3. Nosauciet un definējiet LAMBDA formulu ar vārdu pārvaldnieku
  4. Pārbaudiet jauno pielāgoto funkciju, izmantojot noteikto nosaukumu

Tālāk sniegtajos piemēros šīs darbības ir sīkāk aplūkotas.

1. piemērs

Lai ilustrētu LAMBDA darbību, sāksim ar ļoti vienkāršu formulu:

=x*y // multiple x and y

Programmā Excel šī formula parasti izmanto šādu šūnu atsauces:

=B5*C5 // with cell references

Kā redzat, formula darbojas lieliski, tāpēc mēs esam gatavi pāriet uz vispārīgas LAMBDA formulas (nenosaukta versija) izveidi. Vispirms jāņem vērā, vai formulai ir nepieciešami ievadi (parametri). Šajā gadījumā atbilde ir "jā" - formulai ir nepieciešama vērtība x un vērtība y. Kad tas ir izveidots, mēs sākam ar funkciju LAMBDA un pievienojam nepieciešamos parametrus lietotāja ievadei:

=LAMBDA(x,y // begin with input parameters

Tālāk mums jāpievieno faktiskais aprēķins, x * y:

=LAMBDA(x,y,x*y)

Šajā brīdī ievadot formulu, jūs saņemsiet #CALC! kļūda. Tas notiek tāpēc, ka formulai nav ievades vērtību, ar kurām strādāt, jo vairs nav šūnu atsauču. Lai pārbaudītu formulu, mums jāizmanto šāda sintakse:

=LAMBDA(x,y,x*y)(B5,C5) // testing syntax

Šī sintakse, kurā parametri tiek piegādāti LAMBDA funkcijas beigās atsevišķā iekavu komplektā, ir unikāla LAMBDA funkcijām. Tas ļauj formulu pārbaudīt tieši darblapā, pirms tiek nosaukta LAMBDA. Zemāk redzamajā ekrānā jūs varat redzēt, ka F5 vispārējā LAMBDA funkcija atgriež tieši tādu pašu rezultātu kā sākotnējā formula E5:

Tagad mēs esam gatavi nosaukt LAMBDA funkciju ar nosaukumu pārvaldnieku. Vispirms atlasiet formulu, * beigās neiekļaujot * testēšanas parametrus. Pēc tam atveriet vārdu pārvaldnieku ar saīsni Control + F3 un noklikšķiniet uz Jauns.

Dialoglodziņā Jauns nosaukums ievadiet nosaukumu "XBYY", atstājiet darbgrāmatai iestatīto darbības jomu un ielīmējiet kopēto formulu ievades apgabalā "Atsauces uz".

Pārliecinieties, ka formula sākas ar vienādības zīmi (=). Tagad, kad LAMBDA formulai ir nosaukums, to var izmantot darbgrāmatā tāpat kā jebkuru citu funkciju. Zem ekrāna zemāk nokopētā formula G5 ir:

Jaunā pielāgotā funkcija atgriež to pašu rezultātu kā pārējās divas formulas.

2. piemērs

Šajā piemērā sfēras apjoma aprēķināšanas formulu pārveidosim par pielāgotu LAMBDA funkciju. Vispārējā Excel formula sfēras tilpuma aprēķināšanai ir:

=4/3*PI()*A1^3 // volume of sphere

kur A1 apzīmē rādiusu. Tālāk redzamajā ekrānā redzama šī formula darbībā:

Ievērojiet, ka šai formulai ir nepieciešama tikai viena ievade (rādiuss), lai aprēķinātu tilpumu, tāpēc mūsu LAMBDA funkcijai būs nepieciešams tikai viens parametrs (r), kas parādīsies kā pirmais arguments. Šī ir formula, kas pārveidota par LAMBDA:

=LAMBDA(r,4/3*PI()*r^3) // generic lambda

Atpakaļ darblapā mēs esam aizstājuši sākotnējo formulu ar vispārējo LAMBDA versiju. Ievērojiet, ka mēs izmantojam testēšanas sintaksi, kas ļauj mums pieslēgt B5 rādiusam:

Rezultāti no vispārējās LAMBDA formulas ir tieši tādi paši kā sākotnējā formula, tāpēc nākamais solis ir definēt un nosaukt šo LAMBDA formulu ar nosaukumu pārvaldnieku, kā paskaidrots iepriekš. Funkcijai LAMBDA izmantotais nosaukums var būt jebkurš derīgs Excel nosaukums. Šajā gadījumā mēs nosauksim formulu "SphereVolume".

Atpakaļ darblapā mēs esam aizstājuši vispārīgo (nenosaukto) LAMBDA formulu ar nosaukto LAMBDA versiju un ievadījuši r5 B5. Ievērojiet, ka pielāgotās SphereVolume funkcijas atgrieztie rezultāti ir tieši tādi paši kā iepriekšējie rezultāti.

3. piemērs

Šajā piemērā mēs izveidosim funkciju LAMBDA vārdu skaitīšanai. Excel šim nolūkam nav funkcijas, taču jūs varat skaitīt vārdus ar šūnu ar pielāgotu formulu, pamatojoties uz šādām funkcijām: LEN un SUBSTITUTE:

=LEN(TRIM(A1))-LEN(SUBSTITUTE(A1," ",""))+1

Detalizētu skaidrojumu lasiet šeit. Darblapā ir šāda formula:

Ievērojiet, ka mēs saņemam nepareizu skaitli 1, ja formulai tiek piešķirta tukša šūna (B10). Mēs pievērsīsimies šai problēmai tālāk.

Šai formulai ir nepieciešama tikai viena ievade, tas ir teksts, kas satur vārdus. Mūsu LAMBDA funkcijā mēs šo argumentu nosauksim par "tekstu". Šī ir formula, kas pārveidota par LAMBDA:

=LAMBDA(text,LEN(TRIM(text))-LEN(SUBSTITUTE(text," ",""))+1)

Paziņojums "teksts" parādās kā pirmais arguments, un aprēķins ir otrais un pēdējais arguments. Zemāk redzamajā ekrānā mēs esam aizstājuši sākotnējo formulu ar vispārējo LAMBDA versiju. Ievērojiet, ka mēs izmantojam testēšanas sintaksi, kas ļauj mums pievienot tekstu B5:

=LAMBDA(text,LEN(TRIM(text))-LEN(SUBSTITUTE(text," ",""))+1)(B5)

Rezultāti no vispārējās LAMBDA formulas ir tādi paši kā sākotnējā formula, tāpēc nākamais solis ir definēt un nosaukt šo LAMBDA formulu ar nosaukumu pārvaldnieku, kā paskaidrots iepriekš. Mēs šo formulu nosauksim par "CountWords".

Tālāk mēs esam aizstājuši vispārīgo (nenosaukto) LAMBDA formulu ar nosaukto LAMBDA versiju un tekstam ievadījuši B5. Ievērojiet, ka mēs iegūstam tieši tādus pašus rezultātus.

Formula, kas vārdu pārvaldniekā izmantota CountWords definēšanai, ir tāda pati kā iepriekš, bez testa sintakses:

=LAMBDA(text,LEN(TRIM(text))-LEN(SUBSTITUTE(text," ",""))+1)

Tukšās šūnas problēmas novēršana

Kā minēts iepriekš, iepriekš minētā formula atgriež nepareizu skaitli 1, kad šūna ir tukša. Šo problēmu var novērst, aizstājot +1 ar šādu kodu:

=LEN(TRIM(B5))-LEN(SUBSTITUTE(B5," ",""))+(LEN(TRIM(B5))>0)

Pilns skaidrojums šeit. Lai atjauninātu esošo nosaukto LAMDA formulu, mums atkal jāizmanto vārdu pārvaldnieks:

  1. Atveriet vārdu pārvaldnieku
  2. Atlasiet nosaukumu "CountWords" un noklikšķiniet uz "Rediģēt"
  3. Aizstājiet kodu “Atsaucas uz” ar šo formulu:
=LAMBDA(text,LEN(TRIM(text))-LEN(SUBSTITUTE(text," ",""))+(LEN(TRIM(text))>0))

Kad vārdu pārvaldnieks ir aizvērts, CountWords pareizi darbojas tukšās šūnās, kā redzams zemāk:

Piezīme: vienreiz atjauninot kodu nosaukumu pārvaldniekā, visi CountWords formulas gadījumi tiek atjaunināti vienlaikus. Tas ir galvenais ieguvums no pielāgotajām funkcijām, kas izveidotas, izmantojot LAMBDA -formulas atjauninājumus var pārvaldīt vienuviet.

Interesanti raksti...