Kopsavilkums
Lai aprēķinātu kopējo ienākuma nodokli, pamatojoties uz vairākām nodokļu iekavām, varat izmantot VLOOKUP un likmju tabulu, kas strukturēta, kā parādīts piemērā. G5 formula ir:
=VLOOKUP(inc,rates,3,1)+(inc-VLOOKUP(inc,rates,1,1))*VLOOKUP(inc,rates,2,1)
kur "inc" (G4) un "likmes" (B5: D11) ir nosaukti diapazoni, un D kolonna ir palīgkolonna, kas aprēķina kopējo uzkrāto nodokli katrā kronšteinā.
Fons un konteksts
ASV nodokļu sistēma ir "progresīva", kas nozīmē, ka cilvēki ar augstāku ar nodokli apliekamo ienākumu maksā augstāku federālā nodokļa likmi. Likmes tiek vērtētas iekavās, ko nosaka augšējais un apakšējais slieksnis. Ienākumu summa, kas ietilpst noteiktā iekavās, tiek aplikta ar nodokli pēc attiecīgās likmes šai iekavai. Palielinoties ar nodokli apliekamajam ienākumam, ienākums tiek aplikts ar nodokļiem, izmantojot vairāk nodokļu iekavās. Tāpēc daudzi nodokļu maksātāji maksā vairākas atšķirīgas likmes.
Parādītajā piemērā nodokļu iekavas un likmes ir paredzētas atsevišķiem iesniedzējiem Amerikas Savienotajās Valstīs 2019. taksācijas gadam. Zemāk esošajā tabulā parādīti manuālie aprēķini par ienākumiem, kuru ar nodokli apliek 50 000 USD:
| Kronšteins | Aprēķins | Nodoklis |
|---|---|---|
| 10% | (9 700 USD - 0 USD) x 10% | 970,00 USD |
| 12% | (39 475–9 700 USD) x 12% | 3 573,00 USD |
| 22% | (50 000–39 475 USD) x 22% | 2315,50 USD |
| 24% | NA | 0,00 USD |
| 32% | NA | 0,00 USD |
| 35% | NA | 0,00 USD |
| 37% | NA | 0,00 USD |
Tādējādi kopējais nodoklis ir 6858,50 USD. (parādītajā piemērā parādīts kā 6,859).
Iestatīšanas piezīmes
1. Šī formula ir atkarīga no funkcijas VLOOKUP "aptuvenajā spēles režīmā". Atrodoties aptuvenajā atbilstības režīmā, VLOOKUP skenēs tabulas uzmeklēšanas vērtības (kuras jāšķiro augošā secībā), līdz tiek atrasta lielāka vērtība. Tad tas "atkāpsies" un atgriezīs vērtību no iepriekšējās rindas. Precīzas spēles gadījumā VLOOKUP atgriezīs rezultātus no saskaņotās rindas.
2. Lai VLOOKUP varētu iegūt faktiskās kumulatīvās nodokļu summas, tās ir pievienotas tabulai kā palīgkolonna D slejā. Formula D6, kas nokopēta, ir:
=((B6-B5)*C5)+D5
Katrā rindā šī formula piemēro likmi no iepriekšējās rindas uz ienākumiem šajā iekavās.
3. Lasāmībai ir definēti šādi nosauktie diapazoni: "inc" (G4) un "rate" (B5: D11).
Paskaidrojums
G5 versijā pirmais VLOOKUP ir konfigurēts, lai izgūtu kumulatīvo nodokli ar robežlikmi, izmantojot šādus datus:
- Uzmeklēšanas vērtība ir "inc" (G4)
- Uzmeklēšanas tabula ir "likmes" (B5: D11)
- Kolonnas numurs ir 3, kumulatīvais nodoklis
- Spēles veids ir 1 = aptuvenā atbilstība
VLOOKUP(inc,rates,3,1) // returns 4,543
Ar apliekamo ienākumu 50 000 USD apmērā VLOOKUP aptuvenajā spēles režīmā atbilst 39 475 un atdod 4543, kopējais nodoklis līdz 39 475 USD.
Otrais VLOOKUP aprēķina atlikušos ar nodokli apliekamos ienākumus:
(inc-VLOOKUP(inc,rates,1,1)) // returns 10,525
aprēķināts šādi:
(50 000-39 475) = 10 525
Visbeidzot, trešais VLOOKUP iegūst (augšējo) nodokļu robežlikmi:
VLOOKUP(inc,rates,2,1) // returns 22%
Tas tiek reizināts ar iepriekšējā solī aprēķinātajiem ienākumiem. Pilnīga formula tiek atrisināta šādi:
=VLOOKUP(inc,rates,3,1)+(inc-VLOOKUP(inc,rates,1,1))*VLOOKUP(inc,rates,2,1) =4,543+(10525)*22% =6,859
Marginālās un efektīvās likmes
Šūnā G6 ir augšējā robežlikme, kas aprēķināta, izmantojot VLOOKUP:
=VLOOKUP(inc,rates,2,1) // returns 22%
Faktiskā nodokļa likme G7 ir kopējais nodoklis, dalīts ar apliekamo ienākumu:
=G5/inc // returns 13.7%
Piezīme: Esmu saskāries ar šo formulu Džefa Leninga emuārā, kas atrodas Excel universitātē. Tas ir lielisks piemērs tam, kā VLOOKUP var izmantot aptuvenajā spēles režīmā, kā arī to, kā VLOOKUP var izmantot vairākas reizes vienā formulā.
